Now I am not going to show all the declarations and such - you can download the LSS from here and look at it yourself.

The function code

Function getDirDialog(stitle As String) As String
	REM unless otherwise noted, the functoin calls below came from Declarations (C API)
	Dim iNull As Integer, lpIDList As Long, lResult As Long
	Dim sPath As String
	Dim hwd As Long
	Dim bi As BrowseInfo ' user type declared in declarations
	
	On Error Goto errHandler
	
	hwd = GetForegroundWindow() ' returns the handle to the currently selected program window
	
     REM Set the owner/parent window
	bi.hWndOwner = hwd
	
     REM lstrcat appends the two strings and returns the memory address;
	'   even though we're using one string, we use lstrcat to get a pointer
	'   to a memory address, instead of using the string directly
	'   NOTE: You can change the text here if you want
	If stitle = "" Then stitle = "Choose a folder for your attachment(s)"
	bi.lpszTitle = lstrcat(stitle, "")
	
	REM this next parameter is a bit flag; we're flipping bits with the constants
	REM this flag ensures a return only if the user selected a directory
	bi.ulFlags = BIF_RETURNONLYFSDIRS
	REM this flag lets us have a "Make New Folder" button, resize the dlg, etc.
	bi.ulFlags = bi.ulFlags Or BIF_NEWDIALOGSTYLE
	REM if you DON'T want a "Make New Folder" button, you can uncomment the next flag
'	bi.ulFlags = bi.ulFlags Or BIF_NONEWFOLDERBUTTON
	
	REM the rest of this simply preps all of the parameters and loads the dialog itself
	lpIDList = SHBrowseForFolder(bi)
	If lpIDList Then
		sPath = String$(MAX_PATH, 0)
		SHGetPathFromIDList lpIDList, sPath   'Get the path from the IDList
		CoTaskMemFree lpIDList   'free the block of memory
		iNull = Instr(sPath, Chr(0))
		If iNull Then
			sPath = Left$(sPath, iNull - 1)
		End If
	End If
	
	REM return the path
	getDirDialog = spath
	
getOut:
	Exit Function
	
errHandler:
	On Error Goto 0
	Error Err, Error$ & "(" & Err & ") [in " & Lsi_info(2) & ", line: " & Erl & "]"
	Resume getOut
End Function

There are a couple of main points I want to bring out in this code.

The GetForegroundWindow call is a Win32 C API call that returns a handle (long) to the program window that is in the foreground - in this case the Notes client. The handle is needed to pass to the SHBrowseForFolder function as a part of the BrowseInfo data type, so that the dialog has a "parent" window.

I wrote the getDirDialog function so that you can pass in your own title/instructions for the dialog. If you send an empty string in, then it will assign the default title of "Choose a folder for your attachment(s)".

Notice that when the stitle is passed into the lpszTitle parameter of the BrowseInfo data type it is passed via the lstrcat function. lstrcat is a C API function that takes two strings, munges them together, and then returns a memory pointer for where resulting string is stored. The lpszTitle parameter wants a memory pointer to the string, not the string itself, so this is the easiest way to get that.

The "ulflags" parameter in the BrowseInfo data type is a bit flag, so you use bitmasks to "flip" the bits you want. There are a ton of constants giving you a variety of parameters in the (Declarations); I am simply flipping the minimal bits to give you the dialog box pictured above.

The SHBrowseForFolder(bi) call returns a memory pointer to a complex data type. The If statement below the call parses the contents of that memory pointer using the SHGetPathFromIDList call, where it places the returned path in the sPath variable (which is a string variable set to MAX_PATH size). Then the memory is freed using the CoTaskMemFree call, and the null-terminated string in sPath is parsed to get the returned path in a LotusScript-digestable format.

Conclusion
I hope you find this call as useful as I have. Now you can create even more robust applications providing Win32 users the dialog boxes they have come to know in their OS, which helps make Notes more acceptable as a "standard" application.

Enjoy!

Rock
**Fun is a good thing but only when it spoils nothing better. - George Santayana