Category Technical
Bookmark :              


I have been working on a new version of the Signature File Wizard (I'll post it later), and I realized that I had partially hardcoded the "My Documents" directory. I didn't want to do that, so I went to look for programmatic way to discover this directory for the user. I did a quick Google for it, didn't find anything, so then I went to my handy-dandy API Guide (remember this? I blog about it frequently when talking about C API calls) and did a quick search, and discovered the calls to make this happen.

Now, before I proceed, let me give full disclosure. I did another search right before writing this blog entry, and actually found an entry posted a couple of days' ago by Mikkel Heisterberg on his blog (Lekkim's World). He wrote about this exact thing in his Show-n-Tell Thursday post here, but I noticed that the API call he makes is different from the technique I found in the API Guide. So, since variety is the spice of life I am offering my way as well. Is one better than the other? I don't know. His is a bit simpler (one less call), but I do have more contants for finding other interesting directories as well. In any case they both work, so now you have a choice - go crazy!

First, I needed to set up some stuff in the (Declarations) of my code:

Const DESKTOP_DIR = &H0			' \My Documents
Const START_PROGRAMS = &H2		' \Windows\Start Menu\Programs
Const CONTROLS_DIR = &H3		' returns blank - virtual folder containing icons for the control panel applications
Const PRINTERS_DIR = &H4		' returns blank - virtual folder containing installed printers 
Const MY_DOCUMENTS = &H5		' \My Documents
Const FAVORITES_GRYPHON = &H6 		' \Windows\Start Menu
Const STARTUP_DIR = &H7			' \Windows\StartUp
Const RECENT_DIR = &H8			' \Recent
Const SENDTO_DIR = &H9			' \SendTo
Const BITBUCKET = &HA			' returns blank - file system directory containing file objects in the user recycle bin. 
					' The location of this directory is not in the registry; it is marked with the 
					' hidden and system attributes to prevent the user from moving or deleting it.

Const STARTMENU_DIR = &HB		' \Windows\Start Menu
Const DESKTOPDIRECTORY = &H10		' seems to be the same as DESKTOP_DIR (&H0)
Const DRIVES = &H11			' returns blank - supposed to be virtual folder containing everything on the 
					' local computer: storage devices, printers, and Control Panel.

Const NETWORK_DIR = &H12		' returns blank - virtual folder representing the top level of the network hierarchy.
Const NETHOOD_DIR = &H13		' \NetHood
Const FONTS_DIR = &H14			' \Windows\Fonts
Const TEMPLATES_DIR = &H15		' \Templates
Const FAVORITES_DIR = &H16		' \Windows\Favorites
Const MY_PICTURES = &H27		' \My Documents\My Pictures

Const MAX_PATH = 260

Private Type SHITEMID
	cb As Long
	abID As Byte
End Type
Private Type ITEMIDLIST
	mkid As SHITEMID
End Type

Declare Function SHGetPathFromIDList Lib "shell32.dll" Alias "SHGetPathFromIDListA" (Byval pidl As Long, Byval pszPath As String) As Long
Declare Function SHGetSpecialFolderLocation Lib "shell32.dll" (Byval hwndOwner As Long, Byval nFolder As Long, pidl As ITEMIDLIST) As Long

As you can see, I tested each constant to see what it returned. Some returned nothing, so I looked in API Guide to see what they were supposed to return. In all cases they were "virtual folders", so there is probably a way to get a return value but from this call they return blank. The rest of the constants returned good values, and I have made comments after each constant to let you know what I found. Hope this helps!

Now we have the constants defined, we have defined some small complex data types that are needed for our two calls, and we have declared our Win32 C API functions.

Function getSpecialfolder(CSIDL As Long) As String
	Dim r As Long
	Dim IDL As ITEMIDLIST
	Dim fpath As String
	
	On Error Goto errHandler
	
    'Get the special folder
	r = SHGetSpecialFolderLocation(100, CSIDL, IDL)  ' in Delcarations
	If r = 0 Then
        'Create a buffer
		fpath = Space$(512)
        'Get the path from the IDList
		r = SHGetPathFromIDList(IDL.mkid.cb, fpath) ' in Declarations
        'Remove the unnecessary chr$(0)'s
		GetSpecialfolder = Left$(fpath, Instr(fpath, Chr$(0)) - 1)
		Exit Function
	End If
	GetSpecialfolder = ""
	
getOut:
	Exit Function
errHandler:
	On Error Goto 0
	getSpecialFolder = ""
	Error Err, Error$ & " [in " & Lsi_info(2) & ", line: " & Erl & "]"
	Resume getOut
End Function