Category Show-n-Tell Thursday
Bookmark :              

Last year I wrote an entry about some code I wrote that replaced the Notes feature known as "launch first attachment". I explained the technique I used to Bob Balaban the other day, and he thought it was another "righteous hack", and he suggested I use it for a Show-n-Tell Thursday entry. I remembered I had written it up before, but since that original writeup I have enhanced it a bit, and I have also created an example database to demonstrate it; therefore I think it is time to cover it again.

When designing a form you have the ability to set its launch properties - you can decide what happens when the form is used to open a document. One of the choices available is "First Attachment", as shown in the figure below:



When First Attachment is chosen then the first attachment in the document is opened instead of the form when a document using the form is opened. If the document is opened in Edit mode from the view (such as by selecting the document and hitting CTRL-E) then the document is opened with the form in edit mode (handy for changing the attachment, or changing other field values, etc.). This works great for applications that contain such things as Excel spreadsheets, reports, etc. - things where the "important" information is contained in the attachment, and the database is simply a repository. However, there is a bug with this feature - and it is a bug that has been around for quite some time.

The problem is that certain programs, such as MS Excel and Word, launch but don't maintain focus; while others, such as MS Powerpoint, do launch with focus. The real aggravation with this bug is for users who use Notes open full-screen, and have their taskbars hidden. In this scenario the user will double-click the document to open the attachment, and to them, nothing happens. So, they double-click it again. And again. And then they eventually call support to ask what's going on, only to find out they have opened the same attachment 35 times in the background, all because the attachment didn't have focus when opened (and therefore the user didn't know it was opening). This problem has been around for quite some time (as noted in Technote 1091159), with no plans to fix. But there is a way to give your users the convenience of this feature without the annoying focus problem - and here's how.

First, I recommend you download the example database from here. Got it? Good.

	REM I only want to launch the first attachment if the doc isn't new, 
	REM and if it isn't being edited (like the notes feature)
	If Source.IsNewDoc = False And Source.EditMode = False Then
		Set doc = Source.Document
		retflg = detachFileOpen(doc, "Attach") ' from LS.utilities.FE.6
		Continue = False
	End If

Function detachFileOpen(doc As NotesDocument, rtname As String) As Variant
	On Error Goto errHandler
	detachFileOpen = True
	Dim ws As New NotesUIWorkspace
	Dim rtitem As NotesRichTextItem
	Dim filepath As String, filename As String
	Dim retflg As Boolean, res As Long, res2 As Integer
	Dim exepath As String, shellpath As String
	
	exepath = String(MAX_FILENAME_LEN, 32)
	retflg = detachFile(doc, rtname, filename, filepath)
	
	REM determine if the file is an EXE - if it is, we just want to launch it
	If Lcase(Right(Fulltrim(filepath), 3)) = "exe" Then
		res2 = Shell(filepath, 1)
		Exit Function
	End If
	
	REM use the C API call to find the associated executable
	res = FindExecutable(filepath, "", exepath)
	If res <= 32 Then Error 1000, "Problem with FindExecutable call."
	
	exepath = Fulltrim(Left$(exepath, Instr(exepath, Chr$(0)) - 1)) ' remove trailing spaces
	
	REM can't launch a DLL
	If Ucase$(Strrightback(exepath, ".")) = "DLL" Then Error 1001, "Unable to locate associated program"
	If exepath = "" Then Error 1001, "Unable to locate associated program"
	
	shellpath = exepath & | "| & filepath & |"|
	
	REM open the file with the associated executable
	REM the "1" param tells it to launch with focus
	res2 = Shell(shellpath, 1)
	
getOut:
	Exit Function
errHandler:
	detachFileOpen = False
	Select Case Err
	Case 1001
		Msgbox Error$, 48, "Error"
	Case Else
		On Error Goto 0
		Error Err, Error$ & " (" & Err & ") [in " & Lsi_info(2) & "]"
	End Select
	Resume getOut
End Function